TextLinkAds | The Leader in Text Link Search Engine Optimization

ASP Installation Instructions

Signup and Site Submission Required to fully install plugin.

The two final steps:

Create a file named local_59431.xml that is writable by the web server. The file should be blank and it should be located in the same directory as the script below. On Windows you will need to access your custom control panel to set the permissions or contact your hosting company. You may also do this via ftp.
Copy the code below and paste it into the appropriate pages on http://www.yourdomain.com.

Version 1.1.4

Ad Code

<%@ Language=VBScript %>
<%
' Local file to store XML
' You must create a blank file named "local_59431.xml" in the same
' directory as this script. It MUST be writable by the web
' server. On unix you would CHMOD 666 the file. On Windows
' you will need to access your custom control panel to set
' the permissions or contact your hosting company.

Const ForReading = 1, ForWriting = 2

Dim LOCAL_XML_FILENAME, sourceFile, FSO

LOCAL_XML_FILENAME = server.MapPath("local_59431.xml")
sourceFile = "http://www.text-link-ads.com/xml.php?k=XXXXXXJOINtextlinkadsFORKEYXXXXXX&l=asp-tla-1.1.4"
Set FSO = server.createObject("Scripting.FileSystemObject")

' update local XML
Dim DateMod, MonthString, DayString, DateModFile, DateModLimit

DateMod = FSO.getFile(LOCAL_XML_FILENAME).DateLastModified

MonthString = Month(DateMod)
If (MonthString < 10) Then
    MonthString = "0" & MonthString
End If

DayString = Day(DateMod)
If (DayString < 10) Then
    DayString = "0" & DayString
End If

DateModFile = Year(DateMod) & "-" & MonthString & "-" & DayString & " " & Hour(DateMod) & ":" & Minute(DateMod) & ":" & Second(DateMod)

MonthString = Month(Date)
If (MonthString < 10) Then
    MonthString = "0" & MonthString
End If

DayString = Day(Date)
If (DayString < 10) Then
    DayString = "0" & DayString
End If

DateModLimit = Year(Date) & "-" & MonthString & "-" & DayString & " " & (Hour(Now)-1) & ":" & Minute(Now) & ":" & Second(Now)

Dim Contents, Result, xmlhttp, TextStream

' read local XML
Contents = ""
Set TextStream = FSO.OpenTextFile(LOCAL_XML_FILENAME, ForReading, False, -1)
Do While Not TextStream.AtEndOfStream
    Contents = Contents & TextStream.ReadLine
Loop
TextStream.Close
Set TextStream = nothing

If (DateModFile < DateModLimit Or FSO.getFile(LOCAL_XML_FILENAME).size < 20) Then
    ' fetch remote XML
    Set xmlhttp = CreateObject("Microsoft.XMLHTTP")
    xmlhttp.open "GET", sourceFile, False
    xmlhttp.send ""
    Result = xmlhttp.responseText
    If (Result <> "") Then
        Contents = Result
    End If

    ' write new XML to local file
    Set TextStream = FSO.OpenTextFile(LOCAL_XML_FILENAME, ForWriting, True,-1)
    TextStream.Write Contents
    TextStream.Close
    Set TextStream = nothing
End If

' parse local XML
Dim source
Set source = Server.CreateObject("Microsoft.XMLDOM")
source.async = false
source.loadXML(Contents)

' Output links
Dim objLst, i, numLinks, objLink, objLinkChildren, linkNode, URL, Text, BeforeText, AfterText

Set objLst = source.getElementsByTagName("Link")
numLinks = objLst.length

If numLinks > 0 Then
    Response.Write("<ul>")
    For i = 0 To numLinks -1
        Set objLink = objLst.item(i)
        Set objLinkChildren = objLink.childNodes
        URL = ""
        Text = ""
        BeforeText = ""
        AfterText = ""
    
        For Each linkNode In objLinkChildren
            If linkNode.nodeName = "URL" Then
                URL = linkNode.text
            End If
            If linkNode.nodeName = "Text" Then
                Text = linkNode.text
            End If
            If linkNode.nodeName = "BeforeText" Then
                BeforeText = linkNode.text
            End If
            If linkNode.nodeName = "AfterText" Then
                AfterText = linkNode.text
            End If
        Next
    
        Response.Write("<li>" & BeforeText & " <a href=""" & URL & """>" & Text & "</a> " & AfterText & "</li>")
    Next
    Response.Write("</ul>")
End If
%>